请教关于加强版伤害计算公式的问题

石头的头

我想问一下关于加强版伤害计算公式是怎样的，如果论坛里有，请给个地址，谢谢了.
希望能稍微详细点

石头的头

老大们，哥哥们，给个回复撒........

[发帖际遇]: 石头的头帮周威信押镖，结果：偷得鸳鸯刀，转手卖得银两21。

weyl

只有源码……
function CalHurtValue(bnum1, bnum2, mnum, level: integer): integer;
var
  i, rnum1, rnum2, mhurt, att, def, k1, k2, dis, temp: integer;
begin
  //计算双方武学常识
  k1 := 0;
  k2 := 0;
  for i := 0 to broleamount - 1 do
  begin
    if (Brole[i].Team = brole[bnum1].Team) and (Brole[i].Dead = 0) and (rrole[Brole[i].rnum].Knowledge > MIN_KNOWLEDGE) then k1 := k1 + rrole[Brole[i].rnum].Knowledge;
    if (Brole[i].Team = brole[bnum2].Team) and (Brole[i].Dead = 0) and (rrole[Brole[i].rnum].Knowledge > MIN_KNOWLEDGE) then k2 := k2 + rrole[Brole[i].rnum].Knowledge;
  end;
  rnum1 := Brole[bnum1].rnum;
  rnum2 := Brole[bnum2].rnum;
  mhurt := Rmagic[mnum].Attack[level - 1];

  att := Rrole[rnum1].Attack + k1 * 3 div 2 + mhurt div 3;
  def := Rrole[rnum2].Defence * 2 + k2 * 3;

  case Rmagic[mnum].MagicType of
    1:
      begin
        att := att + Rrole[rnum1].Fist;
        def := def + Rrole[rnum2].Fist * 3 div 2;
      end;
    2:
      begin
        att := att + Rrole[rnum1].Sword;
        def := def + Rrole[rnum2].Sword * 3 div 2;
      end;
    3:
      begin
        att := att + Rrole[rnum1].Knife;
        def := def + Rrole[rnum2].Knife * 3 div 2;
      end;
    4:
      begin
        att := att + Rrole[rnum1].Unusual;
        def := def + Rrole[rnum2].Unusual * 3 div 2;
      end;
  end;
  
  //攻击, 防御按伤害的折扣
  att := att * (100 - Rrole[rnum1].Hurt div 2) div 100;
  def := def * (100 - Rrole[rnum2].Hurt div 2) div 100;

  //如果有武器, 增加攻击, 检查配合列表
  if rrole[rnum1].Equip[0] >= 0 then
  begin
    att := att + ritem[rrole[rnum1].Equip[0]].AddAttack;
    for i := 0 to MAX_WEAPON_MATCH - 1 do
    begin
      if (rrole[rnum1].Equip[0] = matchlist[i, 0]) and (mnum = matchlist[i, 1]) then
      begin
        att := att + matchlist[i, 2] * 2 div 3;
        break;
      end;
    end;
  end;
  //防具增加攻击
  if rrole[rnum1].Equip[1] >= 0 then att := att + ritem[rrole[rnum1].Equip[1]].AddAttack;
  //武器, 防具增加防御
  if rrole[rnum2].Equip[0] >= 0 then def := def + ritem[rrole[rnum2].Equip[0]].AddDefence;
  if rrole[rnum2].Equip[1] >= 0 then def := def + ritem[rrole[rnum2].Equip[1]].AddDefence;
  //showmessage(inttostr(att)+' '+inttostr(def));
  result := att - def + random(20) - random(20);
  temp := att div 15 + random(4) - random(4);
  if result < temp then result := temp;
  dis := abs(brole[bnum1].X - brole[bnum2].X) + abs(brole[bnum1].Y - brole[bnum2].Y);
  if dis > 10 then dis := 10;
  result := result * (100 - (dis - 1) * 3) div 100;
  if (result <= 0) or (level <= 0) then result := random(10) + 1;
  if (result > 9999) then result := 9999;
  //showmessage(inttostr(result));

end;

[[i] 本帖最后由 weyl 于 2008-9-11 23:45 编辑 [/i]]

石头的头

大概能明白点了。。。。。。

[发帖际遇]: 石头的头帮周威信押镖，结果：偷得鸳鸯刀，转手卖得银两20。

石头的头

谁能给个通俗说法就好了